跪求一个详细的单片机定时闹钟程序:
功能如下:用AT89C51单片机结合LED数码显示器。显示格式为“时时:分分”;由LED闪动来做秒计数表示:一旦时间到则发出声响,同时继电器启动。
程序执行后工作指示灯led闪动,表示程序开始执行,led显示“00:00”,按下操作键K1~~K4动作如下:(1)K1设置现在的时间。(2)K2显示闹钟设置时间(3)设置闹铃的时间(4)K4闹铃开关的状态设置,设置为ON时连续三次发出“哗”的一声,设置为OFF发出哗的一声。
设置当前时间或闹铃时间如下:(1)k1时调整(2)K2分调整(3)k3设置完成(4)K4闹铃时间到,发出一阵声响,按下本键可以停止响声
程序参考
;---------------------------------------------------------------------
;文件名称:nz.ASM
;程序功能:定时闹钟
;--------------------------------------------------------------------
; ---------------------------- 程序初始化-----------------------
; 定义存放计时单元地址
;....................
ALB EQU 20H.0 ;闹铃设置标志
;....................
BUF EQU 30H ;30~33H 连续4字节存放显示器数据
HOUR EQU 34H ;存放小时变量
MIN EQU 35H ;存放分钟变量
SEC EQU 36H ;存放秒钟变量
DEDA EQU 37H ;存放5 ms 计数值
;....................
HH EQU 38H ;闹铃设置小时变量
MM EQU 39H ;闹铃设置分钟变量
;....................
;按键输入引脚定义
K1 EQU P2.4 ;按键K1引脚定义
K2 EQU P2.5 ;按键K2引脚定义
K3 EQU P2.6 ;按键K3引脚定义
K4 EQU P2.7 ;按键K4引脚定义
;蜂鸣器和指示灯引脚定义
SPK EQU P3.4 ;蜂鸣器控制信号引脚
WLED EQU P1.0 ;工作指示灯引脚定义
;程序开始执行地址
ORG 0H ;程序代码由地址0开始
AJMP MAIN
ORG 0BH ;定时器T0 中断地址设置
AJMP TO_SRV
;------------------------------- 主程序 -------------------------------
MAIN: ;主程序标号
;...................
CLR ALB ;清除闹铃标志
;...................
ACALL BZ ;蜂鸣器连续两次鸣响一声
ACALL BZ
ACALL LED_SD ;LED 闪动,表示程序开始执行
ACALL INIT ;初始变化量
ACALL INIT_TIMER ;设置定时器
;加载显示器初值数据
MOV A, #0C0H
MOV P0, A
;无穷循环
LOOP: ;无穷循环
ACALL CONV ;转换 时时 分分 数据
;....................
ACALL TIME_PRO ;检查闹铃时间
;....................
ACALL DISP ;扫描显示
JB K1, M1 ;未按下K1键则继续扫描
ACALL LED_SD ;LED闪动
ACALL SET_TIME ;设置目前时间
AJMP LOOP ;跳转到LOOP处执行
;设置闹铃时间
M1:JB K2, M2 ;未按下K2键则继续扫描
;.....................
ACALL LED_SD
ACALL SET_ATIME ;设置闹铃时间
;.....................
AJMP LOOP ;跳转到LOOP处执行
M2: JB K3, M3 ;未按下K3键则继续扫描
AJMP LOOP ;跳转到LOOP处执行
M3: JB K4, M4 ;未按下K4键则继续扫描
;...................
CPL ALB
JNB ALB, M31
;闹铃启动连续3次发出响声
ACALL BZ
ACALL BZ
ACALL BZ
;...................
AJMP LOOP ;跳转到LOOP处执行
;....................
M31:
ACALL BZ ;闹铃停止,发出一声响
AJMP LOOP ;跳转到LOOP处执行
;...................
M4:
AJMP LOOP ;跳转到LOOP处执行
;------------------------- 定时中断模块 -------------------
;定时器T0模式0计时
INIT_TIMER: ;初始化定时器
MOV TMOD,#00000000B ;设置定时器T0工作模式0
MOV IE, #10000010B ;启用定时器T0中断产生
MOV TL0, #(8192-4900)MOD 32 ;加载初始值
MOV TH0, #(8192-4900)/32
SETB TR0 ;启动定时器T0开始计时
RET
;--------------------------
;中断服务程序
TO_SRV: ;定时器T0计时中断程序每隔5ms中断一次
PUSH ACC ;将A值压入堆栈
MOV TL0, #(8192-4900)MOD 32 ;重加载初始值
MOV TH0, #(8192-4900)/32
INC DEDA ;加1
;秒输出
MOV A, DEDA
CJNE A, #200, TT1 ;是否1s到了
MOV DEDA, #0 ;计数值清除为0
CPL WLED ;LED灯亮灭变换
INC SEC ;秒计数加1
MOV A, SEC
CJNE A, #60, TT1 ;是否1min到了
;分输出
INC MIN ;分计数加1
MOV SEC, #0 ;秒计数清除为0
MOV A, MIN
CJNE A, #60, TT1 ;是否1h到了
;时输出
INC HOUR ;小时计数加1
MOV MIN, #0 ;分计数清除为0
MOV A, HOUR
CJNE A,#24, TT1 ;是否24h到了
MOV SEC, #0 ;秒钟变量清除为0
MOV MIN, #0 ;分钟变量清除为0
MOV HOUR, #0 ;小时变量清除为0
TT1:
POP ACC ;将A值由堆栈取出
RETI
;---------------------------------------- 转换十进制模块---------------------------------
CONV: ; 转换十进制子程序
;转换小时数据
MOV DPTR,#TABLE ;存表
MOV A, HOUR
MOV B, #10
DIV AB
MOVC A, @A+DPTR ;查表转换
MOV BUF, A
MOV A, B
MOVC A, @A+DPTR
MOV BUF+1, A
;转换分钟数据
MOV A, MIN
MOV B, #10
DIV AB
MOVC A, @A+DPTR ;查表转换
MOV BUF+2, A
MOV A, B
MOVC A, @A+DPTR ;查表转换
MOV BUF+3, A
RET
;字型数据编码表
TABLE:
DB 0C0H,0F9H,0A4H,0B0H
DB 99H,92H,82H,0F8H
DB 80H,90H,88H,83H
DB 0C6H,0A1H,86H,8EH
;-------------------------------------- 扫描显示模块 ------------------------------------
DISP: ;扫描显示子程序
MOV R0, #BUF ;指向显示器显示缓冲区起始地址
MOV R2, #4 ;执行4次循环
MOV ACC, #11110111b ;加载扫描信号初值11110111B
S1:
PUSH ACC
MOV A, @R0 ;读取出显示器数据
MOV P0, A ;由P0送出一位显示器数据
POP ACC
MOV P2, ACC ;由P2送出扫描输出信号
MOV R5, #2 ;延迟一段时间
ACALL DELAY1MS_R5
;改变扫描码 EX:XXXX1011
RR A ;累加器A向右移动一位
INC R0 ;显示器显示缓冲区地址加1
DJNZ R2, S1 ;判断是否继续执行循环
RET
;-------------------------------------- 调整时间模块 ------------------------------------
SET_TIME: ;设置目前时间子程序
CLR TR0 ;定时器工作暂停
MOV SEC, #0 ;秒钟变量清除为0
L0:
ACALL DISP ;扫描显示
JB K2, L1 ;未按下K2键则继续扫描
JNB K2, $ ;有按下则等待放开
;K2小时调整
INC HOUR ;小时计数加1
MOV A, HOUR
CJNE A,#24, L11 ;是否24H到了
MOV HOUR, #0 ;小时变量清除为0
L11:
ACALL CONV ;转换显示数据
ACALL DISP ;扫描显示
AJMP L0 ;继续程序执行
L1: JB K3, L2 ;未按下K3键则继续扫描
JNB K3,$ ;有按下则等待放开
;K3分钟调整.
INC MIN ;分钟计数加1
MOV A, MIN
CJNE A, #60, L21 ;是否60 min到了
MOV MIN, #0 ;分钟变量清除为0
L21:
ACALL CONV ;转换显示数据
ACALL DISP ;扫描显示
AJMP L0 ;跳转到L0处执行
L2: JB K4,L0 ;未按下K4键则继续扫描
JNB K4, $ ;有按下则等待放开
ACALL BZ ;蜂鸣器鸣响一声
;K4设置完成
ACALL LED_SD ;LED闪动
SETB TR0 ;启动定时器
RET
;------------------------------------- 计时单元清零模块 -------------------------------
INIT: ;计时单元清零子程序
MOV DEDA, #0 ;5ms计数值清除为0
MOV SEC, #0 ;秒钟变量清除为0
MOV MIN, #0 ;分钟变量清除为0
MOV HOUR, #0 ;小时变量清除为0
RET
;-------------------------------------- 蜂鸣器鸣响模块--------------------------------------
BZ: ;蜂鸣器鸣响一声子程序
MOV R6, #250
B1: ACALL DEX
CPL SPK
DJNZ R6,B1
MOV R5, #50
ACALL DELAY1MS_R5
RET
;------------------------------------- LED闪动模块 -------------------------------------
LED_SD: ;工作指示灯闪烁子程序
MOV R4,#6
LE1:CPL WLED ;位反向
MOV R5,#25
ACALL DELAY1MS_R5
DJNZ R4, LE1 ;延迟50ms
RET
;------------------------------------------ 延时模块 --------------------------------------
DELAY1MS_R5: ;总延迟时间 2ms×R5
MOV R6,#10
D1:MOV R7,#100
DJNZ R7,$
DJNZ R6, D1
DJNZ R5, DELAY1MS_R5
RET
;------------------------------------------ 短暂延时模块 ---------------------------------
DEX: ;短暂延时子程序
MOV R7,#180
DE1: NOP
DJNZ R7, DE1
RET
;********************* 增加定时闹铃程序部分 ********************
;----------------------------------------- 设置闹铃时间模块 --------------------------------
SET_ATIME: ;设置闹铃时间子程序
MOV HH,#0
MOV MM,#0
ACALL CONVA ;加载闹铃时间数据
N0:
ACALL DISP
;-----------
JB K2, N1 ;未按下K2键则继续扫描
JNB K2, $ ;有按下则等待放开
;K2调整小时
INC HH ;小时数加1
MOV A, HH
CJNE A, #24,N11 ;是否24h到了
MOV HH, #0 ;小时清为0
N11:
ACALL CONVA ;加载闹铃时间数据
ACALL DISP ;扫描显示
AJMP N0 ;跳转到N0处执行
;------------
N1: JB K3, N2 ;未按下K3键则继续扫描
JNB K3, $ ;有按下则等待放开
;K3调整分钟
INC MM ;调整分钟数
MOV A,MM ;分钟数加1
CJNE A, #60,N21 ;是否60min到了
MOV MM, #0 ;分钟数清为0
N21:
ACALL CONVA ;加载闹铃时间数据
ACALL DISP
参考资料:新概念51单片机C语言应用